Wi-Fi LED matrix clock

Install first: MD_Parola, MD_MAX72XX, BH1750 by Christopher Laws

#include <WiFi.h>
#include <Wire.h>
#include <BH1750.h>
#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>

const char* WIFI_NAME = "your-wifi";
const char* WIFI_PASS = "your-password";
const char* TZ_INFO   = "IST-5:30";          // POSIX time zone string

const int CS_PIN = 13, TOUCH_PIN = 27;
MD_Parola matrix(MD_MAX72XX::FC16_HW, CS_PIN, 4);   // hardware SPI: MOSI 23, SCK 18
BH1750 light;
char text[32];

void setup() {
  pinMode(TOUCH_PIN, INPUT);
  Wire.begin(21, 22);
  light.begin();
  matrix.begin();
  matrix.setIntensity(2);
  matrix.displayText("WiFi...", PA_CENTER, 0, 0, PA_PRINT);
  matrix.displayAnimate();
  WiFi.begin(WIFI_NAME, WIFI_PASS);
  while (WiFi.status() != WL_CONNECTED) delay(250);
  configTzTime(TZ_INFO, "pool.ntp.org", "time.google.com");
}

void loop() {
  struct tm now;
  if (!getLocalTime(&now)) return;

  float lux = light.readLightLevel();
  matrix.setIntensity(constrain((int)(log10(max(lux, 1.0f)) * 3), 0, 7));   // 0 = faint, 7 is about 300 mA

  if (digitalRead(TOUCH_PIN) == HIGH) {
    strftime(text, sizeof text, "%a %d %b", &now);
    matrix.displayClear();
    matrix.displayScroll(text, PA_LEFT, PA_SCROLL_LEFT, 40);
    while (!matrix.displayAnimate()) delay(5);
  }

  strftime(text, sizeof text, now.tm_sec % 2 ? "%H:%M" : "%H %M", &now);
  matrix.displayText(text, PA_CENTER, 0, 0, PA_PRINT);
  matrix.displayAnimate();
  delay(200);
}